You've already forked torvalds-GuitarPedal
mirror of
https://github.com/torvalds/GuitarPedal.git
synced 2026-08-18 21:26:54 +00:00
0c1b9c3db3
'Software' was the directory everything that was not KiCad ended up in, which stopped describing anything a while ago - Validation and the web app are software too. Worse, it put the shared parts inside the firmware, where they read as the firmware's own. They are not. Effects/ has three consumers built from it: the firmware, Validation's bench, and the web app's controls, all generated from the same POT: comments by gen_effects.py. Audio/ has two - the bench compiles the same biquads, the same envelope followers and the same single_sample(), which is the whole reason a measurement on a workstation says anything about the pedal. Neither belongs under Firmware/, so neither is under it any more: Effects/ one file per effect Audio/ the DSP they are built from, and the audio loop Firmware/ the rest of what runs on the pedal, and the submodules WebMIDI/ the web app scripts/ what the build runs Validation/ unchanged Hardware/, Documentation/, Images/ CMakeLists.txt and the wrapper Makefile move to the top with them, because the build now consumes four of those directories and generates into a fifth. board.local and build/ come along; MIDI_CC_MAP.md is generated into Documentation/ rather than into the old Software/ root. scripts/ goes with the build rather than staying under the firmware, because six of the ten had nothing to do with the firmware: gen_effects.py reads Effects/ and writes to three different places, pow2/log2/quarter_sine generate Audio/'s tables, check-readme.py compares Effects/ against the README, and server.py serves the web app. Four of them are invoked from Validation, which was reaching into Firmware/ for tooling - the same burying this commit is undoing. The four that really are about the firmware are ELF checks the top-level build drives anyway, and a second scripts directory would only be a second place to look. C includes say "Audio/foo.h" and the generated map says "Effects/bar.h", with the repository root on the include path for both the firmware and the bench. Spelling the directory out rather than relying on a bare name is what keeps Audio/cycles.h shimmable: a quoted include searches the including file's own directory first. The submodules are renamed as well as moved. git mv updates their paths but leaves the section names, and 'Software/pico-sdk' surviving in .gitmodules would be the word this commit removes, still load-bearing. That meant the nested modules under pico-sdk too - six .git files pointing into .git/modules/Software - which is why 'git submodule update --init --recursive' is worth running once after pulling this. Verified rather than assumed: a clean configure and build, make check (failing only on the missing-eeprom case it already failed on), check-effects, all four analysis pages reproducing every series and drawing every chart, and a flash to the board that still measures a routed reverb where it did before. One latent bug fell out of it. bench/coeff declared only quarter_sine.h of the three generated math tables, and Audio/util.h includes pow2.h and log2.h as well - so building that target with an empty gen/ could never have worked. 'make bench' builds bench/bench first, which generates all three, so it stayed hidden until this rebuilt everything from nothing. Signed-off-by: Linus Torvalds <torvalds@linux-foundation.org>
75 lines
1.4 KiB
Plaintext
75 lines
1.4 KiB
Plaintext
;
|
|
; We use a PIO divisor of 15,000 which means that
|
|
; we run the PIO block at 10kHz
|
|
;
|
|
|
|
.pio_version 1
|
|
.program debounce
|
|
.clock_div 15000
|
|
|
|
.wrap_target
|
|
start:
|
|
wait 0 jmppin [10]
|
|
|
|
; Ok, we've seen the pin go low.
|
|
; Now we need to see a stable value
|
|
newzero:
|
|
set x,31
|
|
Xrepzero:
|
|
set y,31
|
|
Yrepzero:
|
|
jmp pin newone [10]
|
|
jmp y-- Yrepzero
|
|
jmp x-- Xrepzero
|
|
|
|
; We've seen only zeroes for one second: report longpress
|
|
; x is all ones, push it
|
|
mov isr, x
|
|
push block
|
|
|
|
; Now wait for it to be released, and then quietly
|
|
; wait for a new one without sending a new key event
|
|
quietzero:
|
|
wait 1 jmppin [10]
|
|
quietnewone:
|
|
set x,31
|
|
quietrepone:
|
|
jmp pin quietstillone [10]
|
|
jmp quietzero
|
|
quietstillone:
|
|
jmp x-- quietrepone
|
|
jmp start
|
|
|
|
newone:
|
|
set x,31
|
|
repone:
|
|
jmp pin stillone [10]
|
|
jmp newzero
|
|
stillone:
|
|
jmp x-- repone
|
|
|
|
; We've seen only ones for 30ms: report shortpress
|
|
; x is all ones, !x is zero
|
|
mov isr, !x
|
|
push block
|
|
.wrap
|
|
|
|
% c-sdk {
|
|
static inline void debounce_program_init(PIO pio, uint sm, uint offset, uint pin)
|
|
{
|
|
pio_sm_config c = debounce_program_get_default_config(offset);
|
|
|
|
// Initialize the pin to be the PIO jmp pin
|
|
pio_sm_set_consecutive_pindirs(pio, sm, pin, 1, false);
|
|
sm_config_set_jmp_pin(&c, pin);
|
|
|
|
// Load and run the program
|
|
pio_sm_init(pio, sm, offset, &c);
|
|
pio_sm_set_enabled(pio, sm, true);
|
|
|
|
pio_set_irq0_source_enabled(pio,
|
|
pio_get_rx_fifo_not_empty_interrupt_source(sm),
|
|
true);
|
|
}
|
|
%}
|